Функция UNIQUE в Excel

Функция UNIQUE в Excel возвращает список уникальных значений в списке или диапазоне. Значениями могут быть текст, числа, даты, время и т. д.

Что делает функция UNIQUE в Excel?

Функция UNIQUE в Excel извлекает уникальные значения из диапазона.

Возвращаемое значение

Массив уникальных значений.

Аргументы

  • array — диапазон или массив, из которого можно извлечь уникальные значения.
  • by_col — [необязательно] Как сравнить и извлечь. По строке = FALSE (по умолчанию); по столбцу = TRUE.
  • exactly_once — [необязательно] TRUE = значения, которые встречаются один раз, FALSE = все уникальные значения (по умолчанию).

Синтаксис

=UNIQUE(array, [by_col], [exactly_once])

Примечания по использованию

Функция UNIQUE в Excel извлекает список уникальных значений из диапазона или массива. Результатом является динамический массив уникальных значений. Если этот массив является конечным результатом (т.е. не передан другой функции), значения массива «переместятся» на рабочий лист в диапазон, который автоматически обновляется при добавлении или удалении новых уникальных значений из исходного диапазона.

Функция UNIQUE в Excel принимает три аргумента: array, by_col и exactly_once. Первый аргумент array — это массив или диапазон , из которого необходимо извлечь уникальные значения. Это единственный обязательный аргумент. Второй аргумент, by_col, определяет, будет ли UNIQUE извлекать уникальные значения по строкам или по столбцам. По умолчанию функция извлекает уникальные значения из строк. Чтобы заставить UNIQUE извлекать уникальные значения по столбцам, установите для параметра by_col значение TRUE или 1.

Последний аргумент, exactly_once,устанавливает поведение для значений, которые появляются более одного раза. По умолчанию UNIQUE извлекает все уникальные значения, независимо от того, сколько раз они встречаются в массиве. Чтобы извлечь уникальные значения, которые появляются в массиве только один раз, задайте для exactly_once значение TRUE или 1.

Примечание. Функция UNIQUE не учитывает регистр. UNIQUE будет считать «APPLE», «Apple» и «apple» одним и тем же текстом.

Базовый пример

Функция UNIQUE извлекает уникальные значения из диапазона или массива:

=UNIQUE({"A";"B";"C";"A";"B"}) // returns {"A";"B";"C"}

Чтобы вернуть уникальные значения из диапазона A1:A10, вы можете использовать такую ​​формулу:

=UNIQUE(A1:A10)

По столбцу

По умолчанию UNIQUE извлекает уникальные значения в строках:

=UNIQUE({1;1;2;2;3}) // returns {1;2;3}

UNIQUE не будет обрабатывать одни и те же значения, организованные в столбцы:

=UNIQUE({1,1,2,2,3}) // returns {1,1,2,2,3}

Чтобы обработать приведенный выше горизонтальный массив , установите для аргумента by_col значение TRUE или 1:

=UNIQUE({1,1,2,2,3},1) // returns {1,2,3}

Чтобы вернуть уникальные значения из горизонтального диапазона A1:E1, установите для аргумента by_col значение TRUE или 1:

=UNIQUE(A1:E1,1) // извлечение уникальных значений из горизонтального массива

Ровно один раз

Функция UNIQUE имеет необязательный аргумент, называемый exactly_once, который управляет тем, как функция обрабатывает повторяющиеся значения. По умолчанию exactly_once имеет значение FALSE. Это означает, что UNIQUE будет извлекать уникальные значения независимо от того, сколько раз они встречаются в исходных данных:

=UNIQUE({1;1;2;2;3}) // returns {1;2;3}

Установите для  точно_once  значение TRUE или 1, чтобы извлечь уникальные значения, которые появляются в исходных данных только один раз:

=UNIQUE({1;1;2;2;3},0,1) // returns {3}

Обратите внимание, что приведенная выше формула также устанавливает для аргумента by_col значение ноль (0), значение по умолчанию. Эту же формулу можно записать и так:

=UNIQUE({1;1;2;2;3},,1) // returns {3}
=UNIQUE({1;1;2;2;3},,TRUE) // returns {3}
=UNIQUE({1;1;2;2;3},FALSE,TRUE) // returns {3}

Уникальный с критериями

Чтобы извлечь уникальные значения, соответствующие определенным критериям, вы можете использовать UNIQUE вместе с функцией FILTER . Общая формула, где rng2=A1 представляет собой логический тест, выглядит следующим образом:

=UNIQUE(FILTER(rng1,rng2=A1))

Автор А. Днепров

Обучаю основам работы с офисными программами.

Функция UNIQUE в Excel
Красный крестик рядом с файлами и папками в OneDrive: как убрать