Функция SEQUENCE в Excel

Функция SEQUENCE (ПОСЛЕДОВАТЕЛЬНОСТЬ) в Excel создает список последовательных чисел в массиве. Массив может быть одномерным или двумерным, определяемым аргументами строк и столбцов.

Что делает функция SEQUENCE в Excel?

Функция SEQUENCE (ПОСЛЕДОВАТЕЛЬНОСТЬ) в Excel получает массив списка последовательных чисел.

Возвращаемое значение

Массив последовательных значений

Аргументы

  • rows — количество возвращаемых строк.
  • columns — [необязательный] Количество возвращаемых столбцов.
  • start — [необязательный] Начальное значение (по умолчанию 1).
  • step — [необязательный] Приращение между каждым значением (по умолчанию 1).

Синтаксис

=SEQUENCE(rows, [columns], [start], [step])

Примечания по использованию

Функция SEQUENCE создает список последовательных чисел в массиве. Массив может быть одномерным или двумерным, управляемым аргументами строк и столбцов. Функцию можно использовать отдельно для создания массива последовательных чисел, которые выводятся непосредственно на рабочий лист.

Также можно использовать для создания числового массива внутри другой формулы — требование, которое часто возникает в более сложных формулах.

Функция SEQUENCE принимает четыре аргумента: строки, столбцы, начало и шаг. Все значения по умолчанию равны 1. Аргументы rows и columns управляют количеством строк и столбцов, которые должны быть сгенерированы в выходных данных. Например, приведенные ниже формулы генерируют числа от 1 до 5 в строках и столбцах:

=SEQUENCE(5,1) // вернет {1;2;3;4;5} в 5 строк
=SEQUENCE(1,5) // вернет {1,2,3,4,5} в 5 столбцов

Обратите внимание, что вывод SEQUENCE представляет собой массив значений, которые будут распространяться на соседние ячейки. Синтаксис для ПОСЛЕДОВАТЕЛЬНОСТИ указывает, что требуются строки, но строки или столбцы могут быть опущены:

=SEQUENCE(5) // вернет {1;2;3;4;5} в 5 строк
=SEQUENCE(,5) // вернет {1,2,3,4,5} в 5 столбцов

Аргумент start — это начальная точка в числовой последовательности, а шаг управляет приращением между каждым значением. Обе приведенные ниже формулы используют начальное значение 10 и шаговое значение 5:

=SEQUENCE(3,1,10,5) // вернет {10;15;20} в 3 ряда
=SEQUENCE(1,3,10,5) // вернет {10,15,20} в 3 столбца

Примеры

В примере на экране выше формула в ячейке B4 выглядит так:

=SEQUENCE(10,5,0,3)

В этой конфигурации SEQUENCE возвращает массив последовательных чисел, 10 строк по 5 столбцов, начиная с нуля и увеличиваясь на 3. В результате получается 50 чисел, начиная с 0 и заканчивая 147, как показано на экране.

Положительный и отрицательный

SEQUENCE может работать как с положительными, так и с отрицательными значениями. Чтобы считать от -10 до нуля с шагом 2 в строках, установите для строк значение 6, для столбцов значение 1, для начала значение -10 и для шага значение 2:

=SEQUENCE(6,1,-10,2) // вернет {-10;-8;-6;-4;-2;0}

Для обратного отсчета от 10 до нуля:

=SEQUENCE(11,1,10,-1) // вернет {10;9;8;7;6;5;4;3;2;1;0}

Последовательность дат

Поскольку даты Excel являются порядковыми номерами, вы можете легко использовать ПОСЛЕДОВАТЕЛЬНОСТЬ для создания последовательных дат. Например, чтобы сгенерировать список из 10 дней, начинающихся сегодня, в столбцах, вы можете использоватьSEQUENCEс функцией TODAY.

=SEQUENCE(1,10,TODAY(),1)

Чтобы сгенерировать список из 12 дат, соответствующих первому дню месяца для всех месяцев в году (в данном случае 2022), вы можете использовать ПОСЛЕДОВАТЕЛЬНОСТЬ с функциями DATE и EDATE:

=EDATE(DATE(2022,1,1),SEQUENCE(12,1,0))

Чтобы сгенерировать список имен за двенадцать месяцев (вместо дат), вы можете обернуть приведенные выше формулы в функцию TEXTследующим образом:

=TEXT(EDATE(DATE(2022,1,1),SEQUENCE(12,1,0)),"mmmm")

Автор А. Днепров

Обучаю основам работы с офисными программами.

Функция SEQUENCE в Excel
Функция RANDBETWEEN в Excel