Функция MINIFS в Excel

Функция MINIFS в Excel возвращает наименьшее числовое значение в ячейках, соответствующих нескольким условиям, называемым критериями. Для определения критериев MINIFS поддерживает логические операторы (>,<,<>,=) и подстановочные знаки (*,?,~) и может применять условия к ячейкам, содержащим даты, числа и текст.

Что делает функция MINIFS в Excel?

Функция MINIFS в Excel возвращает минимальное значение с помощью критериев.

Возвращаемое значение

Минимальное значение.

Аргументы

  • min_range — диапазон значений, используемый для определения минимума.
  • range1 — первый диапазон для оценки.
  • criteria1 — критерии для использования в диапазоне 1.
  • range2 — [необязательно] Второй диапазон для оценки.
  • criteria2 – [необязательно] Критерии, используемые в диапазоне2.

Синтаксис

=MINIFS(min_range, range1, criteria1, [range2], [критерий2], …)

Примечания по использованию

Функция MINIFS возвращает наименьшее числовое значение в ячейках, соответствующих нескольким условиям, называемым критериями. Для каждого условия предусмотрен отдельный диапазон и критерии. Для определения критериев MINIFS поддерживает различные логические операторы (>,<,<>,=) и подстановочные знаки (*,?,~).

Синтаксис, используемый для применения критериев немного сложен, поскольку он необычен для Excel.

Синтаксис

Синтаксис функции MINIFS зависит от оцениваемых критериев. Для каждого условия предусмотрен отдельный диапазон и критерии. Общий синтаксис MINIFS выглядит следующим образом:

=MINIFS(min_range,range1,criteria1) // 1 условие
=MINIFS(min_range,range1,criteria1,range2,criteria2) // 2 условия

Функция MINIFS принимает три обязательных аргумента: мин_диапазон, диапазон1 и критерий1. С этими тремя аргументами MINIFS возвращает минимальное число в min_range , где соответствующие ячейки в  диапазоне1 соответствуют условию, установленному критериями1. Дополнительные условия применяются с использованием пар диапазон/критерий. Второе условие определяется  диапазоном2 и критериями2, третье условие —  диапазоном3 и критериями3 и так далее. MINIFS может обрабатывать до 126 пар диапазон/критерий.

При использовании MINIFS имейте в виду следующее:

  • Каждое новое условие требует отдельного диапазона и критериев .
  • Чтобы включиться в окончательный результат, все условия должны быть TRUE.
  • Если ни одна ячейка не соответствует заданным критериям, MINIFS вернет ноль (0).
  • Функция автоматически игнорирует пустые ячейки, соответствующие заданным критериям.
  • MINIFS требует диапазон ячеек для аргументов диапазона; вы не можете использовать массив.
  • Функция вернет #VALUE! ошибка, если размер критерия_диапазона не совпадает с размером минимального_диапазона.

Критерии

Функция MINIFS поддерживает логические операторы (>,<,<>,=) и подстановочные знаки (*,?) для частичного сопоставления. Поскольку MINIFS входит в группу из восьми функций, которые разделяют логические критерии на две части, синтаксис немного сложен. Для каждого условия требуется отдельный диапазон и критерии, а операторы необходимо заключать в двойные кавычки («»). В таблице ниже показаны некоторые распространенные примеры:

Цель Критерии
Клетки больше 75 «>75»
Ячейки равны 100 100 или «100»
Ячейки меньше или равны 100 «<=100»
Ячейки, равные «красному» «красный»
Ячейки, не равные «красному» «<>красный»
Ячейки пустые «» «»
Ячейки, которые не пусты «<>»
Ячейки, начинающиеся с «X» «X*»
Ячейки меньше A1 «<«&A1
Клеток меньше, чем сегодня «<«&СЕГОДНЯ()

Обратите внимание, что в последних двух примерах используется конкатенация с символом амперсанда (&). Если аргумент критерия включает значение из другой ячейки или результат формулы, логические операторы, такие как «<», должны быть объединены конкатенацией. Это связано с тем, что Excel необходимо сначала оценить ссылки на ячейки и формулы, чтобы получить значение, прежде чем это значение можно будет присоединить к оператору.

Базовый пример

На листе, показанном выше, формулы в G5 и G6:

=MINIFS(D5:D16,C5:C16,"F") // возвращает 72
=MINIFS(D5:D16,C5:C16,"M") // возвращает 64

В первой формуле MINIFS возвращает минимальное значение в D5:D16, где C5:C16 равно «F» (72). Во второй формуле возвращает минимальное значение в D5:D16, где C5:C16 равно «M» (64).

Два критерия

В приведенном ниже примере функция MINIFS используется с двумя критериями: одним для пола и одним для группы. Условия примечания добавляются в парах диапазон/критерий. Диапазон E5:E16 сочетается с условием «B».

Формулы в H5:I6:

=MINIFS(D5:D16,C5:C16,"F",E5:E16,"A") // возвращает 72
=MINIFS(D5:D16,C5:C16,"F",E5:E16,"B") // возвращает 83
=MINIFS(D5:D16,C5:C16,"M",E5:E16,"A") // возвращает 65
=MINIFS(D5:D16,C5:C16,"M",E5:E16,"B") // возвращает 64

Другие критерии

Чтобы вернуть минимальное значение в A1:A100, когда ячейки в B1:B100 больше 50:

=MINIFS(A1:A100,B1:B100,">50")

Чтобы получить минимальное значение в A1:A100, когда ячейки в B1:B100 меньше или равны 100, а ячейки в C1:C100 больше нуля:

=MINIFS(A1:A100,B1:B100,"<=100",C1:C100,">0")

Не равно

Чтобы создать критерий «не равно», используйте оператор «<>», заключенный в двойные кавычки («»). Например, чтобы вернуть минимальное значение в A1:A100, когда ячейки в B1:B100 не равны «красному»:

=MINIFS(A1:A100,B1:B100,"<>red")

Значение из другой ячейки

При использовании значения из другой ячейки в условии ссылка на ячейку должна быть объединена  с оператором. Например, чтобы вернуть минимальное значение в A1:A100, когда ячейки в B1:B100 больше значения в C1:

=MINIFS(A1:A100,B1:B100,">"&C1)

Обратите внимание, что оператор «больше» (>) заключен в кавычки («»), а ссылка на ячейку (C1) — нет.

Подстановочные знаки

В критериях можно использовать подстановочные знаки: вопросительный знак (?), звездочку (*) или тильду ( ~ ) . Вопросительный знак (?) соответствует любому одному символу, а звездочка (*) соответствует нулю или более символам. Например, чтобы вернуть минимальное значение в A1:A100, если ячейки в B1:B100 начинаются с «a»:

=MINIFS(A1:A100,B1:B100,"a*")

Тильда (~) — это escape-символ, позволяющий находить буквальные подстановочные знаки. Например, чтобы соответствовать буквальному вопросительному знаку (?), звездочке (*) или тильде (~), добавьте тильду перед подстановочным знаком (т. е. ~?, ~*, ~~).

Примечания

  • Условия применяются с использованием пар диапазон/критерий.
  • MINIFS вернет ошибку #VALUE, если размер какого-либо диапазона критериев не совпадает с размером  min_range.
  • Если ни один критерий не соответствует, функция вернет ноль (0).
  • MINIFS в эксель игнорирует пустые ячейки, соответствующие критериям.
Автор А. Днепров

Обучаю основам работы с офисными программами.

Функция MINIFS в Excel
Функция CLEAN в Excel